How can I plot a scatter plot over a heatmap with a different color gradient?

schwob · July 1, 2024, 8:56pm

I want to overlay a scatter plot onto a heatmap, where the points in the scatter plot are colored based on values at those points. If the values of the scatter points are in the same range as the heatmap’s values, this is pretty easy. However, if the scatter points have a different range/scale than the heatmap, then the plot with the smaller range of variables gets washed out.

For example, in the following code, the heatmap values in Grid_mat fall in [0,1] and Y~N(0,5), which results in a significantly larger range than the Grid_mat values. So, the heatmap becomes less informative, because the color limits are linked between the two plots. I even tried specifying different clims for the two plots, but that didn’t fix the problem.

using Plots, Distributions
using Plots.PlotMeasures

# Example data
x = 1:10
y = 1:10
Grid_mat = rand(1, 100)
ngridpoints = 10
n=50
locs = [rand(Uniform(1, 10), n) rand(Uniform(1, 10), n)]
Y = rand(Normal(0, 5), n)

# Create the heatmap with the first color scale
heatmap(x, y, reshape(Grid_mat[1, :], ngridpoints, ngridpoints),
    color = :viridis, title = "", xlabel = "", ylabel = "",
    clim = (minimum(Grid_mat[1, :]), maximum(Grid_mat[1, :])), alpha = 0.5, legend = false)
scatter!(locs[:, 1], locs[:, 2], marker_z = Y,
    clim = (minimum(Y), maximum(Y)), color = :viridis, msw = 0.25, c = :viridis, legend = false, colorbar = true)

How can I plot the heatmap such that the color limits are for the heatmap values and overlay a scatter plot with color limits that are only for the scatter point values? Note that I do not want to rescale Grid_mat nor Y.

rafael.guerra · July 2, 2024, 12:25am

Using Plots.jl and pgfplotsx() you can get something like this:

Plots.jl dual colorbar code

using Distributions, Measures, Plots, pgfplotsx()

# Example data
x = y = 1:10
Grid_mat = rand(100)
ngridpoints, n = 10, 50
locs = [rand(Uniform(1, 10), n) rand(Uniform(1, 10), n)]
Y = rand(Normal(0, 5), n)

# Create the heatmap with the first color scale
heatmap(x, y, reshape(Grid_mat, ngridpoints, ngridpoints),
    color=:grays, title="", label="", widen=false,
    clim=extrema(Grid_mat), alpha=0.5, legend=false, colorbar=:left,
    xlims=extrema(x), ylims=extrema(y)

)

scatter!(twinx(), eachcol(locs)..., marker_z=Y, xmirror=true, widen=false,
    clim=extrema(Y), color=:viridis, msw=0.25, legend=false, colorbar=:right,
    xlims=extrema(x), ylims=extrema(y)
)

anowacki · July 2, 2024, 12:32pm

Unfortunately this isn’t possible in general with Plots.jl as far as I understand it:

github.com/JuliaPlots/Plots.jl

Allow multiple clims within same subplot

opened 04:27PM - 16 Aug 18 UTC

anowacki

enhancement

As far as I understand, it isn't currently possible to plot multiple times with …different 'z' axes on the same 2D subplot. Being able to do this would be very helpful. By this I mean that one can plot using different colour maps and limits on these and each layer preserves its original limits. I have often wanted the following to work: ```julia julia> using Plots julia> x1 = y1 = 0:π/11:π x2 = y2 = 0:π/101:π nx1, ny1 = length.((x1, y1)) p = heatmap(x1, y1, rand(nx1, ny1).+10, c=:gray, cbar=false) contour!(p, x2, y2, sin.(x2).*sin.(y2)', c=:rainbow, xlim=extrema(x2), ylim=extrema(y2), levels=0:0.2:1, cbar=true, clim=(0,1)) ``` What I expect to happen is that the underlying heatmap has limits automatically scaled to be in the range [10,11], and the overlying contours are plotted with their own scale in [0,1], and we would see some contours on top of a heatmap. Ideally, one would be able to have multiple colourbars, but I recognise that's hard whilst Plots uses native colourbars. If we issue these commands in series we can see how the limits are changed and the heatmap becomes invisible: ```julia julia> x1 = y1 = 0:π/11:π x2 = y2 = 0:π/101:π nx1, ny1 = length.((x1, y1)) p = heatmap(x1, y1, rand(nx1, ny1).+10, c=:gray, cbar=false) ``` ![heatmap](https://user-images.githubusercontent.com/1231209/44221159-87207980-a178-11e8-85a6-fd9ae7d59481.png) which is as expected, ```julia julia> contour!(p, x2, y2, sin.(x2).*sin.(y2)', c=:rainbow, xlim=extrema(x2), ylim=extrema(y2), levels=0:0.2:1, cbar=true, clim=(0,1)) ``` ![contour](https://user-images.githubusercontent.com/1231209/44221195-a28b8480-a178-11e8-9d90-3356cc09e3e6.png) whereas now the heatmap colour scale is saturated at the new z scale. In the past I have hacked around this by scaling all the different layers to have the same limits (e.g. for [this figure](https://ars.els-cdn.com/content/image/1-s2.0-S0377027317306571-gr4.jpg) where I plot topography, colours and contours) but it would be great if this could be done automatically.

schwob · July 2, 2024, 5:15pm

That looks great! What is the code that you used to generate this graphic?

schwob · July 2, 2024, 5:15pm

Is there a different plotting library in Julia that would work? I’m not tied to the Plots package.

sdanisch · July 2, 2024, 5:26pm

I’m not sure if I understand the problem, but Makie should work fine:

using Distributions, GLMakie

# Example data
x = 1:10
y = 1:10
Grid_mat = rand(1, 100)
ngridpoints = 10
n = 50
locs = [rand(Uniform(1, 10), n) rand(Uniform(1, 10), n)]
Y = rand(Normal(0, 5), n)

# Create the heatmap with the first color scale
f, ax, pl = heatmap(x, y, reshape(Grid_mat[1, :], ngridpoints, ngridpoints),
    colormap=:viridis, 
    colorrange=(minimum(Grid_mat[1, :]), maximum(Grid_mat[1, :])), alpha=0.5)

scatter!(ax, locs[:, 1], locs[:, 2], color=Y, colorrange=(minimum(Y), maximum(Y)), colormap=:viridis, )
f

lmiq · July 2, 2024, 5:51pm

In Plots/GR you can set the colorscale of the markers by hand, like:

julia> using Plots

julia> m = [ sin(x * y) for x in x, y in y ];

julia> heatmap(m)

julia> scatter!(1:10, 1:10; markercolor = [Plots.cgrad(:viridis)[i*20] for i in 10:-1:1])

rafael.guerra · July 2, 2024, 7:32pm

Please find below the image above the Plots.jl code used to generate a dual colorbar scatterplot on top of a heatmap.

joa-quim · July 2, 2024, 8:04pm

Another option

using GMT

G = peaks(N=128);

# Interpolate the grid on scattered locations
xy = [(rand(50)*6 .- 3) (rand(50)*6 .- 3)];
Dxyz = grdtrack(G, xy);

# Colormaps for the image and the scatter
cmap1 = makecpt(G, C=:gray);
cmap2 = makecpt(G, C=:turbo);

grdimage(G, cmap=cmap1, colorbar=true)
scatter!(Dxyz, marker=:circ, color=cmap2, zcolor=Dxyz[:,3], colorbar=(position=(outside=true,anchor=:MR, offset=(2,0)), frame=:auto), show=1)