How to filter single subject from dataframe

New to Julia
1

I am started learning julia recently. I am working with a dataset where i want to filter all the rows of single ID in a data frame.
can somebody help me to learn this?

2

There is no way to do that in an “easy” way right now in DataFrames.

If your ID are unique, you can do

df[findfirst(==("idnum"), df.ID), :] |> first
  • findfirst(==("idnum"), df.ID) finds the furst occurance of "idnum" in df.ID
  • The indexing will return a DataFrame with one row. You call first to get a DataFrameRow which is a nicer object for this purpose.
1 Like
3

Thank you

4

Trying to understand the question and how different it is from the following MWE:

using DataFrames

team = DataFrame(ID=[1,2,3,4,2,4],name=["John","Jane","Jim","Joe","Jay","Julia"])

team[team.ID .== 4, :]

which for the input:

│ Row │ ID    │ name   │
│     │ Int64 │ String │
├─────┼───────┼────────┤
│ 1   │ 1     │ John   │
│ 2   │ 2     │ Jane   │
│ 3   │ 3     │ Jim    │
│ 4   │ 4     │ Joe    │
│ 5   │ 2     │ Jay    │
│ 6   │ 4     │ Julia  │

# produces the filtered result by team ID number 4:
│ Row │ ID    │ name   │
│     │ Int64 │ String │
├─────┼───────┼────────┤
│ 1   │ 4     │ Joe    │
│ 2   │ 4     │ Julia  │

Or should the output sought consist of only the teams with one member each (i.e., 1 and 3):

using StatsBase

dic = countmap(team.ID)
ix = [dic[x]==1 for x in team.ID]
team[ix,:] 

│ Row │ ID    │ name   │
│     │ Int64 │ String │
├─────┼───────┼────────┤
│ 1   │ 1     │ John   │
│ 2   │ 3     │ Jim    │

Thanks.

1 Like
5

I think it’s assumed that IDs uniquely identify observations here.

6

this will already return DataFrameRow

1 Like
7

and to make sure you have only one row just write:

only(team[team.ID .== 4, :])

or

only(filter(:ID => ==(4), team))
3 Likes
8

@bkamins, thanks for the feedback. That command throws an error when run for the non-unique ID-rows (2 and 4):

ERROR: ArgumentError: data frame must contain exactly 1 row

Why not throwing an empty data frame instead (if such creature exists)?

NB: the MWE above using countmap() outputs only the ID rows with multiplicity=1. May it be written more simply within DataFrames framework?

9

I used only to show that you can use it to check you get a result that has 1 row (as this was suggested by @pdeffebach above).

Empty data frame DataFrame() exists, but this is not how only is defined in Julia Base (you can check its doctsting to find the contract it guarantees).

NB: the MWE above using countmap() outputs only the ID rows with multiplicity=1. May it be written more simply within DataFrames framework?

julia> DataFrame(filter(sdf -> nrow(sdf)==1, groupby(team, :ID)))
2×2 DataFrame
 Row │ ID     name   
     │ Int64  String 
─────┼───────────────
   1 │     1  John
   2 │     3  Jim

or

julia> combine(groupby(team, :ID), sdf -> nrow(sdf) == 1 ? sdf : DataFrame())
2×2 DataFrame
 Row │ ID     name   
     │ Int64  String 
─────┼───────────────
   1 │     1  John
   2 │     3  Jim
2 Likes