# Why is it so complicated to access a row in a DataFrame?

**URL:** <https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162>\
**Category:** General Usage\
**Tags:** dataframes\
**Created:** [August 24, 2023, 4:53pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162 "2023-08-24T16:53:14Z")\
**Posts on this page:** 14\
**Page:** 1

<div class="post-metadata">

**Author:** ![fdekerme](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/fdekerme/32/43574_2.png) [@fdekerme](https://discourse.julialang.org/u/fdekerme)\
**Post date:** [August 24, 2023, 4:53pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/1 "2023-08-24T16:53:14Z")

</div>

Hello,  
This question has already been asked several times (here for example [How to set a index in Julia's DataFrame? - Stack Overflow](https://stackoverflow.com/questions/75635806/how-to-set-a-index-in-julias-dataframe)) but I still don’t understand why DataFrame.jl doesn’t have an` index_col` parameter like there is in Pandas ([pandas.read\_csv — pandas 2.0.3 documentation](https://pandas.pydata.org/docs/reference/api/pandas.read_csv.html)). Is it because of the internal design of the package?

For example, I’m reading medical data from an Excel table stored in a DataFrame named `df`. Each row corresponds to a patient. It would seem logical that I should be able to access a cell (say age) simply by typing `df[patient_id, age]`.

For the moment, the solution I’ve come up with is to do

```julia
patient_row = filter(row -> row.patient_id == patient_id, df)
patient_rowt[!, ["age"]]

```

Which is incredibly complicated for this simple operation.  
Maybe it’s just me who doesn’t know the right way to do it, in which case I’ll be grateful to anyone who does!

Thanks !  
fdekerm

---

<div class="post-metadata">

**Author:** ![alfaromartino](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/alfaromartino/32/52986_2.png) [@alfaromartino](https://discourse.julialang.org/u/alfaromartino)\
**Post date:** [August 24, 2023, 4:57pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/2 "2023-08-24T16:57:11Z")

</div>

You can simply right  
`df[df.patient_id .== 1234, :age]`

---

<div class="post-metadata">

**Author:** ![Nathan\_Boyer](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/nathan_boyer/32/14825_2.png) [@Nathan\_Boyer](https://discourse.julialang.org/u/Nathan_Boyer)\
**Post date:** [August 24, 2023, 5:48pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/3 "2023-08-24T17:48:37Z")

</div>

I have wanted a simpler way to do this in the past too. The short versions are somewhat hard to discover on your own.

- `==(value)` is a shorthand for `x -> x == value`.
- `.` syntax retrieves the column you are interested in from the filtered data frame.  
(`df.age` is equivalent to `df[!, :age]`.)
- `only` checks that there is only one value returned and returns it.  
This is needed because you might have duplicate data or have passed a function like `<(value)` that would return multiple rows. I like to pipe `|>` to the `only` function, but you can also just wrap everything inside it `only(filter(...))`.

```julia
julia> df = DataFrame(patient_id = 1:5, age = 26:30)
5×2 DataFrame
 Row │ patient_id age
     │ Int64 Int64
─────┼───────────────────
   1 │ 1 26
   2 │ 2 27
   3 │ 3 28
   4 │ 4 29
   5 │ 5 30

julia> value = 3
3

julia> filter(:patient_id => ==(value), df).age |> only
28

julia> subset(df, :patient_id => ByRow(==(value))).age |> only
28

```

alfaromartino’s solution is shorter, but I dislike having to write `df` twice.  
(You will still probably want to pass the output to `only`.)

> [@alfaromartino](#):
>
> df[df.patient\_id .== 1234, :age]

You may also prefer the [DataFramesMeta.jl](https://github.com/JuliaData/DataFramesMeta.jl) syntax.  
Here the macro `@rsubset` will automatically transform the written code into the `subset` call shown above. It eliminates the need to write `=>` and `ByRow` explicitly.

```julia
julia> using DataFramesMeta

julia> @rsubset(df, :patient_id == value).age |> only
28

```

---

<div class="post-metadata">

**Author:** ![hendri54](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/hendri54/32/9621_2.png) [@hendri54](https://discourse.julialang.org/u/hendri54)\
**Post date:** [August 24, 2023, 5:56pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/4 "2023-08-24T17:56:36Z")

</div>

That would allocate a vector to make the comparison.

I would consider (for nice, readable syntax):

```julia
patient_row(df, id) = findfirst(r -> r.patient_id == id, eachrow(df))
# or `only(findall())` if one wants to ensure that the id is unique

# produes a DataFrameRow if `cols` is Vector
get_patient(df, id, cols) = df[patient_row(df, id), cols] 

```

(assuming each patient corresponds to exactly one row)

---

<div class="post-metadata">

**Author:** ![mbauman](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/mbauman/32/31082_2.png) [@mbauman](https://discourse.julialang.org/u/mbauman)\
**Post date:** [August 24, 2023, 7:12pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/5 "2023-08-24T19:12:36Z")

</div>

3 posts were split to a new topic: [Performance of eachrow(::DataFrame)](https://discourse.julialang.org/t/performance-of-eachrow-dataframe/103165)

---

<div class="post-metadata">

**Author:** ![alfaromartino](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/alfaromartino/32/52986_2.png) [@alfaromartino](https://discourse.julialang.org/u/alfaromartino)\
**Post date:** [August 24, 2023, 7:01pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/8 "2023-08-24T19:01:25Z")

</div>

I think that OP wasn’t asking about the most efficient way, but the simplest approach. If you want to keep your code simple, my recommendation is the following:

```julia
df = DataFrame(id = 1:5, weight= 56:60, age = 26:30)

df[df.id .== 1, :age] # for returning a value/vector

df[df.id .== 1, [:age]] # for returning a df

df[in(1:2).(df.id), :age] # for selecting multiple ids

df[(df.id .== 1) .&& (df.weight .==56), :age] # for multiple conditions

```

---

<div class="post-metadata">

**Author:** ![Nathan\_Boyer](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/nathan_boyer/32/14825_2.png) [@Nathan\_Boyer](https://discourse.julialang.org/u/Nathan_Boyer)\
**Post date:** [August 24, 2023, 7:19pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/9 "2023-08-24T19:19:49Z")

</div>

This will always return a vector:

> [@alfaromartino](#):
>
> `df[df.id .== 1, :age] # for returning a value/vector`

```julia
julia> df = DataFrame(id = 1:5, weight= 56:60, age = 26:30);

julia> df[df.id .== 3, :age]
1-element Vector{Int64}:
 28

```

To return a value, you would need to do one of the following:

```julia
julia> df[df.id .== 3, :age] |> only
28

julia> df[findfirst(df.id .== 3), :age]
28

```

---

<div class="post-metadata">

**Author:** ![bkamins](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/bkamins/32/208538_2.png) [@bkamins](https://discourse.julialang.org/u/bkamins)\
**Post date:** [August 24, 2023, 7:43pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/10 "2023-08-24T19:43:48Z")

</div>

Indeed row-lookup is an important use case. And as it was already commented here it is not easy to design a good API. The biggest issue is that the condition you might want to use could return exactly one row, or multiple rows (where 0 rows is a special case of multiple).

I want to add something more user friendly in 1.7 release. But we need to discuss how you would want to achieve this. The discussion is in:

> <https://github.com/JuliaData/DataFrames.jl/issues/3051>
>
> This is a speculative idea. Maybe we could define \`GroupedDataFrame\` to be calla…ble like this:
> \`\`\`
> (gdf::GroupedDataFrame)(idxs...) = gdf\[idxs\]
> \`\`\`
> In this way instead of writing:
> \`\`\`
> gdf\[("val",)\]
> \`\`\`
> users could write \`gdf("val")\`.
> 
> @nalimilan, @pdeffebach - what do you think?
> 
> Ref: https://discourse.julialang.org/t/any-plan-for-functionality-like-pandas-loc/81134

I assume that your use case is for situation that you expect an exactly one match, so essentially, what you want is a shorter way of writing `only(filter(:id => ==(3), df).age))` (or some alternative syntax already available that was mentioned above). Is this correct?

Can you please comment in the linked issue, so that we can move forward with the decisions?

---

<div class="post-metadata">

**Author:** ![simsurace](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/simsurace/32/30216_2.png) [@simsurace](https://discourse.julialang.org/u/simsurace)\
**Post date:** [August 24, 2023, 8:38pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/11 "2023-08-24T20:38:28Z")

</div>

An important use case I often need: if a table has an index (key column), this defines a mapping between it and any other column, which can then be applied to other tables to add columns according to those mappings. A simple and efficient API for that would be nice (if it does not exist already).

---

<div class="post-metadata">

**Author:** ![bkamins](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/bkamins/32/208538_2.png) [@bkamins](https://discourse.julialang.org/u/bkamins)\
**Post date:** [August 24, 2023, 8:41pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/12 "2023-08-24T20:41:38Z")

</div>

What you describe is handled by joins (if I understand your need correctly).

---

<div class="post-metadata">

**Author:** ![simsurace](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/simsurace/32/30216_2.png) [@simsurace](https://discourse.julialang.org/u/simsurace)\
**Post date:** [August 24, 2023, 9:04pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/13 "2023-08-24T21:04:30Z")

</div>

Joins can handle this but quite slowly in my experience. Instead, I normally use:

```julia
lookup = Dict(df1.key_col .=> df1.value_col)
df2.values = [lookup[key] for key in df2.some_col]

```

But I guess one could argue that I should not be using a DataFrame, but a TypedTables.DictTable.

---

<div class="post-metadata">

**Author:** ![fdekerme](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/fdekerme/32/43574_2.png) [@fdekerme](https://discourse.julialang.org/u/fdekerme)\
**Post date:** [August 25, 2023, 8:13am UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/14 "2023-08-25T08:13:45Z")

</div>

Thank you all for your answers. The solution `df[df.patient_id .== 1234, :age] |> only` seems to be the simplest !

---

<div class="post-metadata">

**Author:** ![fdekerme](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/fdekerme/32/43574_2.png) [@fdekerme](https://discourse.julialang.org/u/fdekerme)\
**Post date:** [August 25, 2023, 8:15am UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/15 "2023-08-25T08:15:25Z")

</div>

Ok, no problem, I’ll go and comment on the git discussion.

In fact, I’m in a fairly simple situation where each line is unique (an id doesn’t appear twice).

---

<div class="post-metadata">

**Author:** ![rocco\_sprmnt21](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/rocco_sprmnt21/32/20127_2.png) [@rocco\_sprmnt21](https://discourse.julialang.org/u/rocco_sprmnt21)\
**Post date:** [August 25, 2023, 9:25pm UTC](https://discourse.julialang.org/t/why-is-it-so-complicated-to-access-a-row-in-a-dataframe/103162/16 "2023-08-25T21:25:43Z")

</div>

```julia

d=Dict(zip(df.id,copy.(eachrow(df[:,2:end]))))

d1=Dict(zip(df.id,Tables.namedtupleiterator(df[:,2:end])))

d[3].age

d1[3].age

d1=Dict(zip(df.id,Tables.namedtupleiterator(df[:,Not(:id)])))
d1[3].age

```