# Type of array containing units from Unitful
**URL:** https://discourse.julialang.org/t/type-of-array-containing-units-from-unitful/103020
**Category:** General Usage
**Tags:** unitful
**Created:** [August 21, 2023, 8:30am UTC](https://discourse.julialang.org/t/type-of-array-containing-units-from-unitful/103020 "2023-08-21T08:30:03Z")
**Posts on this page:** 9
**Page:** 1
### Author:  [@Iddingsite](https://discourse.julialang.org/u/Iddingsite)
#### Post date: [August 21, 2023, 8:30am UTC](https://discourse.julialang.org/t/type-of-array-containing-units-from-unitful/103020/1 "2023-08-21T08:30:03Z")
Hello! I am struggling a bit with types coming from Unitful in arrays. Here is a simple MWE:
```julia
using Unitful
array_unit = [1.0, 3, 4]u"yr"
```
If I look at the type of array\_unit, I obtain this:
```julia
typeof(array_unit)
```
```julia
Vector{Quantity{Float64, ๐, FreeUnits{(yr,), ๐, nothing}}} (alias for Array{Quantity{Float64, ๐, Unitful.FreeUnits{(yr,), ๐, nothing}}, 1})
```
So why does this not work?
```julia
array_unit::Array{Quantity{Float64, Unitful.๐, Unitful.FreeUnits{(Unitful.yr,), Unitful.๐, nothing}}, 1}
```
This throws:
```julia
ERROR: TypeError: in typeassert, expected Vector{Quantity{Float64, ๐, Unitful.FreeUnits{(yr,), ๐, nothing}}}, got a value of type Vector{Quantity{Float64, ๐, Unitful.FreeUnits{(yr,), ๐, nothing}}}
Stacktrace:
[1] top-level scope
@ REPL[13]:1
```
which seems to be the same thing to meโฆ
I am still a bit new to types so maybe I am missing something fondamental here.
Cheers,
---
### Author:  [@sostock](https://discourse.julialang.org/u/sostock)
#### Post date: [August 21, 2023, 9:09am UTC](https://discourse.julialang.org/t/type-of-array-containing-units-from-unitful/103020/2 "2023-08-21T09:09:23Z")
The following works:
```julia
array_unit::Array{Quantity{Float64, Unitful.๐, typeof(Unitful.yr)}, 1}
```
The problem is that `Unitful` customizes how some of its types are printed to make them shorter. So the type that is printed is not the actual type.
In this specific case, `Unitful.yr` is not the same object as the one represented by `yr` in `Unitful.FreeUnits{(yr,), ๐, nothing}`. You can see that if you look at the type of `Unitful.yr`:
```julia
julia> typeof(Unitful.yr)
Unitful.FreeUnits{(yr,), ๐, nothing}
```
`Unitful.yr` is already a `Unitful.FreeUnits` object, while the object that `yr` refers to in the above type signature is a `Unitful.Unit` object (specifically, it is the object `Unit{:Year, ๐}(0, 1//1)` with type `Unit{:Year, ๐}`).
I think the custom printing of `Unit` (making it look as if it were a `FreeUnits`) is really confusing and we should get rid of it, but the type signatures would be _a lot_ longer if we removed customized type printing. Maybe, since we already customize type printing, we should print `Quantity` types in the following way:
```julia
Quantity{Float64, ๐, typeof(yr)}
```
I think this would be an improvement to the printing of `Quantity` types, but doesnโt solve the problem of how `Units` types are displayed.
---
### Author:  [@Jollywatt](https://discourse.julialang.org/u/Jollywatt)
#### Post date: [August 21, 2023, 12:27pm UTC](https://discourse.julialang.org/t/type-of-array-containing-units-from-unitful/103020/3 "2023-08-21T12:27:33Z")
Hmmโฆ perhaps a way to improve pretty printing of `Unitful` types while also achieving copy-into-REPL-ability is to draw inspiration from `@NamedTuple` in Julia โฅv1.5.
Suppose `Unitful` exported a macro so that, for example,
```julia
@Quantity{Float64, ๐, yr} === Quantity{Float64, Unitful.๐, typeof(Unitful.yr)}
```
Then types could be pretty printed as calls to this macro.
I really like that idea.
---
### Author:  [@Iddingsite](https://discourse.julialang.org/u/Iddingsite)
#### Post date: [August 21, 2023, 1:35pm UTC](https://discourse.julialang.org/t/type-of-array-containing-units-from-unitful/103020/4 "2023-08-21T13:35:58Z")
Thx for the explanation, it works indeed. But I still struggle to extend this to what I want to do.
Basically, letโs say I want to create a function that takes an array with Units of Time and update an array without units from the values in s:
```julia
using Unitful
array_unit = [1.0, 3, 4]u"yr"
array_without_unit = similar(array_unit, Float64)
function remove_unit!(array_without_unit::Vector{Float64}, array_unit::Array{Quantity{Float64, Unitful.๐, typeof(Unitful.yr)}, 1})
array_without_unit .= ustrip.(u"s", array_unit)
end
remove_unit!(array_without_unit, array_unit)
```
That works nicely now. But only if the input has yr and is composed of Float64. How can I generalise that for array containing Real and Time units? I have tried a couple of things, but my understanding is not enough to do it.
First, Iโve replaced Float64 by \<:Real like I would do for an array. This doesnโt work:
```julia
function remove_unit2!(array_without_unit::Vector{Float64}, array_unit::Array{Quantity{<:Real, Unitful.๐, typeof(Unitful.yr)}, 1})
array_without_unit .= ustrip.(u"s", array_unit)
end
remove_unit2!(array_without_unit, array_unit)
```
And for the units par, Iโve tried randomly a few things without much success. Is there an easier way?
---
### Author:  [@Jollywatt](https://discourse.julialang.org/u/Jollywatt)
#### Post date: [August 21, 2023, 1:50pm UTC](https://discourse.julialang.org/t/type-of-array-containing-units-from-unitful/103020/5 "2023-08-21T13:50:43Z")
You donโt actually need any type annotations for this to work, in case thatโs not clear.
```julia
function remove_unit!(array_without_unit, array_unit)
array_without_unit .= ustrip.(u"s", array_unit)
end
```
If youโre wanting to dispatch on the quantity dimension, then given the complexity of Unitful types, perhaps it would be better to use a dictionary to associate dimensions with preferred units โฆ
**Edit**
See [Highlighted features ยท Unitful.jl](https://painterqubits.github.io/Unitful.jl/stable/highlights/#Dispatch-on-dimensions) for how to dispatch on dimensions. It looks like you can do
```julia
function remove_unit!(array_without_unit, array_unit::Unitful.Time)
array_without_unit .= ustrip.(u"s", array_unit)
end
```
---
### Author:  [@aplavin](https://discourse.julialang.org/u/aplavin)
#### Post date: [August 21, 2023, 1:55pm UTC](https://discourse.julialang.org/t/type-of-array-containing-units-from-unitful/103020/6 "2023-08-21T13:55:38Z")
> [@Iddingsite](#):
>
> Iโve replaced Float64 by \<:Real like I would do for an array
You need to add `<:` to all types in containers:
`Array{<:Quantity{<:Real, ...}}`
---
### Author:  [@sostock](https://discourse.julialang.org/u/sostock)
#### Post date: [August 21, 2023, 1:59pm UTC](https://discourse.julialang.org/t/type-of-array-containing-units-from-unitful/103020/7 "2023-08-21T13:59:29Z")
> [@Iddingsite](#):
>
> `array_unit::Array{Quantity{<:Real, Unitful.๐, typeof(Unitful.yr)}, 1}`
This doesnโt work because `Quantity{<:Real, Unitful.๐, typeof(Unitful.yr)}` is an abstract type, but the array you are passing has is a concrete element type (which is a subtype of the above). You need to add another `<:` like this:
```julia
array_unit::Array{<:Quantity{<:Real, Unitful.๐, typeof(Unitful.yr)}, 1}
```
> [@Iddingsite](#):
>
> And for the units par, Iโve tried randomly a few things without much success. Is there an easier way?
Yes, there is the `Unitful.Time` type alias, which matches all quantities with time units:
```julia
array_unit::Array{<:Unitful.Time{<:Real}, 1}
```
---
### Author:  [@Iddingsite](https://discourse.julialang.org/u/Iddingsite)
#### Post date: [August 21, 2023, 2:14pm UTC](https://discourse.julialang.org/t/type-of-array-containing-units-from-unitful/103020/8 "2023-08-21T14:14:55Z")
Thx a lot for all the responses! I was aware of the Unitful.Time alias, but could not make it work for arraysโฆ @sostock got me covered ๐
I feel like I still need a bit of time to understand all the implications of `<:` and types but I will get there I guess!
---
### Author:  [@gustaphe](https://discourse.julialang.org/u/gustaphe)
#### Post date: [August 21, 2023, 3:13pm UTC](https://discourse.julialang.org/t/type-of-array-containing-units-from-unitful/103020/9 "2023-08-21T15:13:52Z")
One nice trick to know about when dealing with Unitful shenanigans is `typeof(1u"yr")`.