# Recursive macro call
**URL:** https://discourse.julialang.org/t/recursive-macro-call/46369
**Category:** New to Julia
**Tags:** macros, recursion
**Created:** [September 10, 2020, 10:36am UTC](https://discourse.julialang.org/t/recursive-macro-call/46369 "2020-09-10T10:36:53Z")
**Posts on this page:** 7
**Page:** 1
### Author:  [@fonsp](https://discourse.julialang.org/u/fonsp)
#### Post date: [September 10, 2020, 10:36am UTC](https://discourse.julialang.org/t/recursive-macro-call/46369/1 "2020-09-10T10:36:53Z")
As an exercise, I’m trying to make a macro that turns `@x a b c` into `a = b = c = 1234`.
I tried to write it recursively, but I don’t know how to fix my error ☹
Definition:
```julia
julia> macro x(s::Symbol, ss...)
quote
$(esc(s)) = @x $(esc(ss))...
end
end
julia> macro x()
1234
end
```
Call:
```julia
julia> @x a b c
ERROR: LoadError: MethodError: no method matching @x(::LineNumberNode, ::Module, ::Expr)
Closest candidates are:
@x(::LineNumberNode, ::Module) at REPL[9]:2
@x(::LineNumberNode, ::Module, ::Symbol, ::Any...) at REPL[21]:2
in expression starting at REPL[21]:3
```
Any tips?
(The self-assigned exercise is to write it recursively)
---
### Author:  [@tomerarnon](https://discourse.julialang.org/u/tomerarnon)
#### Post date: [September 10, 2020, 10:44am UTC](https://discourse.julialang.org/t/recursive-macro-call/46369/2 "2020-09-10T10:44:10Z")
Generally one doesn’t write macros as _themselves_ being recursive. Instead, you write a function that works on the input expression, and that function is recursive. The macro calls the recursive function and returns the final expression.
---
### Author:  [@mcabbott](https://discourse.julialang.org/u/mcabbott)
#### Post date: [September 10, 2020, 10:45am UTC](https://discourse.julialang.org/t/recursive-macro-call/46369/3 "2020-09-10T10:45:49Z")
This works…
```julia
julia> macro xx(s, ss...)
quote
$(esc(s)) = @xx $(esc.(ss)...)
end
end;
julia> macro xx()
1234
end
@xx (macro with 2 methods)
julia> (@macroexpand @xx a b c) |> Base.remove_linenums!
quote
a = begin
b = begin
c = 1234
end
end
end
```
although I would do:
```julia
julia> macro y(s::Symbol, ss...)
_y(s, ss...)
end;
julia> _y(s, ss...) = :($(esc(s)) = $(_y(ss...)));
julia> _y() = 1234
_y (generic function with 2 methods)
julia> @macroexpand @y a b c
:(a = (b = (c = 1234)))
```
---
### Author:  [@marius311](https://discourse.julialang.org/u/marius311)
#### Post date: [September 10, 2020, 10:48am UTC](https://discourse.julialang.org/t/recursive-macro-call/46369/4 "2020-09-10T10:48:13Z")
After the 5th or 6th guess at where to put the `esc` 🙂 :
```julia
macro x(s::Symbol, ss...)
quote
$(esc(s)) = $(esc(:(@x $(ss...))))
end
end
macro x()
1234
end
```
---
### Author:  [@fonsp](https://discourse.julialang.org/u/fonsp)
#### Post date: [September 10, 2020, 10:58am UTC](https://discourse.julialang.org/t/recursive-macro-call/46369/5 "2020-09-10T10:58:52Z")
Thanks everyone! And @mcabbott thank you for the tip to call out to functions 🙂
---
### Author:  [@simeonschaub](https://discourse.julialang.org/u/simeonschaub)
#### Post date: [September 10, 2020, 11:07am UTC](https://discourse.julialang.org/t/recursive-macro-call/46369/6 "2020-09-10T11:07:42Z")
You probably don’t want to escape `@x` as well, since that will look for the macro definition in the macro caller’s scope, so if you are defining the macro in a different module and don’t explicitly import it, this will fail. @mcabbott’s solution doesn’t have this problem, because only the arguments are escaped.
---
### Author:  [@marius311](https://discourse.julialang.org/u/marius311)
#### Post date: [September 10, 2020, 11:13am UTC](https://discourse.julialang.org/t/recursive-macro-call/46369/7 "2020-09-10T11:13:29Z")
Good point. Actually I tried @mcabbott’s solution but didn’t think to remove the `::Symbol`, which I guess is crucial (it errors otherwise) for reasons that are currently mysterious to me…