# How to get the eight bit values of a variable with UInt8?
**URL:** https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022
**Category:** New to Julia
**Tags:** binaryio
**Created:** [April 13, 2025, 12:15pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022 "2025-04-13T12:15:39Z")
**Posts on this page:** 12
**Page:** 1
### Author:  [@dk-zen](https://discourse.julialang.org/u/dk-zen)
#### Post date: [April 13, 2025, 12:15pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022/1 "2025-04-13T12:15:39Z")
Now I’m reading a binary file. I have got a 8 bits namely “a”. According to the data description, each bit represents a different meaning, I want to read the value represented by 8 bit bits, how can I do it?
```julia
a = 0x0c # UInt8, little endian
a8 = ? #
a7 = ?
a6 = ?
a5 = ?
a4 = ?
a3 = ?
a2 = ?
a1 = ?
```
---
### Author:  [@sgaure](https://discourse.julialang.org/u/sgaure)
#### Post date: [April 13, 2025, 12:33pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022/2 "2025-04-13T12:33:51Z")
The simplest is:
```julia
julia> a = 0x0c
julia> digits(a, base=2, pad=8)
8-element Vector{Int64}:
0
0
1
1
0
0
0
0
```
---
### Author:  [@dk-zen](https://discourse.julialang.org/u/dk-zen)
#### Post date: [April 13, 2025, 1:52pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022/3 "2025-04-13T13:52:43Z")
Thanks a lot. An elegant answer.
---
### Author:  [@abulak](https://discourse.julialang.org/u/abulak)
#### Post date: [April 13, 2025, 2:30pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022/4 "2025-04-13T14:30:11Z")
you can also do directly
```julia
bits(a::UInt8) = ntuple(i -> (a >> (i-1)) & one(a), 8)
```
which should be faster as it avoids allocation (3 times faster on my machine).
---
### Author:  [@DNF](https://discourse.julialang.org/u/DNF)
#### Post date: [April 13, 2025, 3:05pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022/5 "2025-04-13T15:05:37Z")
> [@abulak](#):
>
> `bits(a::UInt8) = ntuple(i -> (a >> (i-1)) & one(a), 8)`
It generalizes well, also:
```julia
function bits(a::Integer)
N = sizeof(a) * 8
return ntuple(i -> (a >> (i-1)) & one(a), Val(N))
end
```
Example:
```julia
julia> @btime bits(x) setup=(x=rand(Int32))
4.600 ns (0 allocations: 0 bytes)
(0, 1, 1, 0, 1, 1, 0, 0, 0, 0, 1, 1, 1, 0, 1, 1, 0, 1, 1, 0, 1, 0, 0, 1, 1, 0, 1, 1, 1, 0, 1, 0)
```
---
### Author:  [@rfourquet](https://discourse.julialang.org/u/rfourquet)
#### Post date: [April 13, 2025, 3:23pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022/6 "2025-04-13T15:23:30Z")
There is also the Bits.jl package, which is a bit dusty, but has this `bits` function, which just (lazily) wraps an integer as an array of `Bool`s:
```julia
julia> using Bits; bs = bits(0x0c)
<00001100>
julia> collect(bs)
8-element Vector{Bool}:
0
0
1
1
0
0
0
0
julia> bs[4]
true
julia> bs[1:4]
<1100>
```
---
### Author:  [@abulak](https://discourse.julialang.org/u/abulak)
#### Post date: [April 13, 2025, 3:45pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022/7 "2025-04-13T15:45:42Z")
Probably better to use `Base.BitInteger` there at the cost of excluding @rfourquet s BitIntegers.jl 😉 As written this will be not correct for heap allocated integers.
---
### Author:  [@rfourquet](https://discourse.julialang.org/u/rfourquet)
#### Post date: [April 13, 2025, 3:58pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022/8 "2025-04-13T15:58:14Z")
> [@abulak](#):
>
> at the cost of excluding @rfourquet s [BitIntegers.jl](https://juliaregistries.github.io/General/packages/redirect_to_repo/BitIntegers) 😉
😃 Good occasion to bump [Feature request: add an AbstractBitSigned type · Issue #37752 · JuliaLang/julia · GitHub](https://github.com/JuliaLang/julia/issues/37752)
---
### Author:  [@mkitti](https://discourse.julialang.org/u/mkitti)
#### Post date: [April 13, 2025, 4:03pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022/9 "2025-04-13T16:03:01Z")
You can usw bit-wise operations directly.
```julia
julia> a = 0x0c
0x0c
julia> bits = a .>> (0:7) .& 0x1
8-element Vector{UInt8}:
0x00
0x00
0x01
0x01
0x00
0x00
0x00
0x00
julia> f(a,s) = a >> s & 0x1
f (generic function with 1 method)
julia> f.(a, 0:7)
8-element Vector{UInt8}:
0x00
0x00
0x01
0x01
0x00
0x00
0x00
0x00
```
---
### Author:  [@rafael.guerra](https://discourse.julialang.org/u/rafael.guerra)
#### Post date: [April 13, 2025, 4:19pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022/10 "2025-04-13T16:19:54Z")
Using a comprehension:
```julia
a = 0x0c
[!iszero(a & <<(one(a), i)) for i in 0:7]
# result:
8-element Vector{Bool}:
0
0
1
1
0
0
0
0
```
---
### Author:  [@matthias314](https://discourse.julialang.org/u/matthias314)
#### Post date: [April 13, 2025, 6:01pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022/11 "2025-04-13T18:01:43Z")
My package Modulo2.jl has the function `zz2vector`:
```julia
julia> zz2vector(0x0c)
8-element ZZ2Vector:
0
0
1
1
0
0
0
0
```
It works with all bit sizes, including BitIntegers.jl.
---
### Author:  [@danielwe](https://discourse.julialang.org/u/danielwe)
#### Post date: [April 13, 2025, 8:45pm UTC](https://discourse.julialang.org/t/how-to-get-the-eight-bit-values-of-a-variable-with-uint8/128022/12 "2025-04-13T20:45:20Z")
If you’re OK with a string representation, there’s also `bitstring`:
```julia-repl
julia> bitstring(0x0c)
"00001100"
```