# Deleting row and column from an array

**URL:** <https://discourse.julialang.org/t/deleting-row-and-column-from-an-array/28969>\
**Category:** General Usage\
**Tags:** arrays\
**Created:** [September 19, 2019, 9:17pm UTC](https://discourse.julialang.org/t/deleting-row-and-column-from-an-array/28969 "2019-09-19T21:17:24Z")\
**Posts on this page:** 9\
**Page:** 1

<div class="post-metadata">

**Author:** ![mamuniut09](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/mamuniut09/32/9991_2.png) [@mamuniut09](https://discourse.julialang.org/u/mamuniut09)\
**Post date:** [September 19, 2019, 9:17pm UTC](https://discourse.julialang.org/t/deleting-row-and-column-from-an-array/28969/1 "2019-09-19T21:17:24Z")

</div>

Hello all,

I wanted to remove column and row from an array, but couldn’t find any function to do that. For example, if I want to remove the second row and second column from the following array, how can I do that?

`a=[1 0 2; 0 0 0; 3 0 8]`

Any help regarding this would be appreciated.

---

<div class="post-metadata">

**Author:** ![Seif\_Shebl](https://avatars.discourse-cdn.com/v4/letter/s/eada6e/32.png) [@Seif\_Shebl](https://discourse.julialang.org/u/Seif_Shebl)\
**Post date:** [September 20, 2019, 1:03am UTC](https://discourse.julialang.org/t/deleting-row-and-column-from-an-array/28969/2 "2019-09-20T01:03:55Z")

</div>

Assuming row 2 and column 2 are to be removed,

```julia
julia> a=[1 0 2; 0 0 0; 3 0 8]
3×3 Array{Int64,2}:
 1 0 2
 0 0 0
 3 0 8

julia> a = a[1:end .!= 2, 1:end .!= 2]
2×2 Array{Int64,2}:
 1 2
 3 8

```

---

<div class="post-metadata">

**Author:** ![mamuniut09](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/mamuniut09/32/9991_2.png) [@mamuniut09](https://discourse.julialang.org/u/mamuniut09)\
**Post date:** [September 20, 2019, 4:51pm UTC](https://discourse.julialang.org/t/deleting-row-and-column-from-an-array/28969/3 "2019-09-20T16:51:30Z")

</div>

Thank you very much.

---

<div class="post-metadata">

**Author:** ![hendri54](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/hendri54/32/9621_2.png) [@hendri54](https://discourse.julialang.org/u/hendri54)\
**Post date:** [September 20, 2019, 8:11pm UTC](https://discourse.julialang.org/t/deleting-row-and-column-from-an-array/28969/4 "2019-09-20T20:11:51Z")

</div>

See also [dropdims](https://docs.julialang.org/en/v1/base/arrays/#Base.dropdims)

---

<div class="post-metadata">

**Author:** ![Narmina\_Baghirova](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/narmina_baghirova/32/25671_2.png) [@Narmina\_Baghirova](https://discourse.julialang.org/u/Narmina_Baghirova)\
**Post date:** [May 31, 2021, 3:08pm UTC](https://discourse.julialang.org/t/deleting-row-and-column-from-an-array/28969/6 "2021-05-31T15:08:53Z")

</div>

Is there a way to delete several columns and rows ?

---

<div class="post-metadata">

**Author:** ![rafael.guerra](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/rafael.guerra/32/216610_2.png) [@rafael.guerra](https://discourse.julialang.org/u/rafael.guerra)\
**Post date:** [May 31, 2021, 3:34pm UTC](https://discourse.julialang.org/t/deleting-row-and-column-from-an-array/28969/7 "2021-05-31T15:34:47Z")

</div>

Check one way [here](https://stackoverflow.com/questions/58033504/julia-delete-rows-and-columns-from-an-array-or-matix).

---

<div class="post-metadata">

**Author:** ![sijo](https://avatars.discourse-cdn.com/v4/letter/s/da6949/32.png) [@sijo](https://discourse.julialang.org/u/sijo)\
**Post date:** [May 31, 2021, 3:36pm UTC](https://discourse.julialang.org/t/deleting-row-and-column-from-an-array/28969/8 "2021-05-31T15:36:07Z")

</div>

Here are some ways:

```julia
julia> a = [10i+j for i in 1:4, j in 0:4]
4×5 Matrix{Int64}:
 10 11 12 13 14
 20 21 22 23 24
 30 31 32 33 34
 40 41 42 43 44

julia> a[[1; 4:end], 3:end] # Remove rows 2 and 3, colums 1 and 2
2×3 Matrix{Int64}:
 12 13 14
 42 43 44

julia> a[1:end .∉ [[2, 3]], 1:end .∉ [[1, 2]]]
2×3 Matrix{Int64}:
 12 13 14
 42 43 44

julia> using InvertedIndices

julia> a[Not([2,3]), Not([1,2])]
2×3 Matrix{Int64}:
 12 13 14
 42 43 44

# In the last two examples since the removed indices are contiguous we can also use ranges:

julia> a[Not(2:3), Not(1:2)]
2×3 Matrix{Int64}:
 12 13 14
 42 43 44

```

---

<div class="post-metadata">

**Author:** ![rafael.guerra](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/rafael.guerra/32/216610_2.png) [@rafael.guerra](https://discourse.julialang.org/u/rafael.guerra)\
**Post date:** [May 31, 2021, 5:23pm UTC](https://discourse.julialang.org/t/deleting-row-and-column-from-an-array/28969/9 "2021-05-31T17:23:44Z")

</div>

Possibly a different angle:

```julia
a = [10i+j for i in 1:4, j in 0:4]

rmr, rmc = [2, 3], [1, 4] # rows and cols to remove
n, m = size(a)
ir, ic = BitArray(ones(n)), BitArray(ones(m))
ir[rmr] .= 0; ic[rmc] .= 0
a[ir,ic]

```

---

<div class="post-metadata">

**Author:** ![Alejandro\_Quiaro\_San](https://sea2.discourse-cdn.com/julialang/user_avatar/discourse.julialang.org/alejandro_quiaro_san/32/35437_2.png) [@Alejandro\_Quiaro\_San](https://discourse.julialang.org/u/Alejandro_Quiaro_San)\
**Post date:** [April 14, 2022, 3:24pm UTC](https://discourse.julialang.org/t/deleting-row-and-column-from-an-array/28969/10 "2022-04-14T15:24:37Z")

</div>

> [@sijo](#):
>
> `.∉ [[1, 2]]`

Thank you so much. This is what I was looking for