# Abstract Types and StructTypes - error reading AbstractTypes into concrete with JSON3
**URL:** https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897
**Category:** General Usage
**Tags:** question, package, json3, structtypes
**Created:** [May 10, 2021, 3:16pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897 "2021-05-10T15:16:50Z")
**Posts on this page:** 15
**Page:** 1
### Author:  [@djholiver](https://discourse.julialang.org/u/djholiver)
#### Post date: [May 10, 2021, 3:16pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/1 "2021-05-10T15:16:50Z")
Hi,
Believe I am running into a bit of a bug / unexpected behaviour that I can’t seem to work around when extracting an interface into a concrete type having defined more than one in a module.
e.g.: this works:
```julia
using StructTypes, Parameters, JSON3
abstract type ICompute end
StructTypes.StructType(::Type{ICompute}) = StructTypes.AbstractType()
StructTypes.subtypekey(::Type{ICompute}) = :computeName
function StructTypes.subtypes(::Type{ICompute})
(
percentile = Percentile
)
end
struct Percentile <: ICompute
computeName
id
percentiles :: Vector{Float64}
end
StructTypes.StructType(::Type{Percentile}) = StructTypes.Struct()
percentile = JSON3.read("""
{
"computeName": "percentile",
"id": "1",
"percentiles": [10,20,30]
}""", ICompute)
```
works, but trying to extend it to include more abstract types:
```julia
using StructTypes, Parameters, JSON3
abstract type ICompute end
StructTypes.StructType(::Type{ICompute}) = StructTypes.AbstractType()
StructTypes.subtypekey(::Type{ICompute}) = :computeName
function StructTypes.subtypes(::Type{ICompute})
(
percentile = Percentile
)
end
struct Percentile <: ICompute
computeName
id
percentiles :: Vector{Float64}
end
StructTypes.StructType(::Type{Percentile}) = StructTypes.Struct()
abstract type IQuery end
StructTypes.StructType(::Type{IQuery}) = StructTypes.AbstractType()
StructTypes.subtypekey(::Type{IQuery}) = :queryName
function StructTypes.subtypes(::Type{IQuery})
(
dataDominance = DataDominance
)
end
struct DataDominance <: IQuery
queryName
id
percentiles :: Vector{Float64}
end
StructTypes.StructType(::Type{DataDominance}) = StructTypes.Struct()
percentile = JSON3.read("""
{
"computeName": "percentile",
"id": "1",
"percentiles": [10,20,30]
}""", ICompute)
datadominance = JSON3.read("""
{
"queryName": "dataDominance",
"id": "1",
"percentiles": [10,20,30]
}""", IQuery)
```
fails with error:
```julia
ERROR: LoadError: MethodError: no method matching length(::Type{Main.GetMetricModels.DataDominance})
Closest candidates are:
length(!Matched::Union{Base.KeySet, Base.ValueIterator}) at abstractdict.jl:58
length(!Matched::Union{LinearAlgebra.Adjoint{T, S}, LinearAlgebra.Transpose{T, S}} where {T, S}) at C:\buildbot\worker\package_win64\build\usr\share\julia\stdlib\v1.6\LinearAlgebra\src\adjtrans.jl:195
length(!Matched::Union{DataStructures.OrderedRobinDict, DataStructures.RobinDict}) at C:\Users\doliver\.julia\packages\DataStructures\ixwFs\src\ordered_robin_dict.jl:86
```
version info:
Packages info:
Would someone mind trying to run the above and feeding back - I’ve tried myriad combinations and just not been successful.
Regards,
---
### Author:  [@lmiq](https://discourse.julialang.org/u/lmiq)
#### Post date: [May 10, 2021, 5:35pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/2 "2021-05-10T17:35:07Z")
I could not run your code (`Average not defined`). It is a little bit odd to me the concept of writing and reading abstract types from a JSON file (how to know what the structure of the data written?) but I may be not aware of how that works.
Anyway, if you could provide a MWE, that will help.
---
### Author:  [@djholiver](https://discourse.julialang.org/u/djholiver)
#### Post date: [May 10, 2021, 6:34pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/3 "2021-05-10T18:34:07Z")
Hi - thanks for responding - updated the above - I hadn’t removed the other subtypes from the listing.
As to the usage - it’s supported by [Structypes.jl](https://juliadata.github.io/StructTypes.jl/stable/) and I make use of it to facilitate multiple dispatch of computations (and filters) provided by users to an http endpoint on top of a calculation library.
i.e. Percentiles require percentile arguments but Average / Sum wouldn’t but they are both of type “ICompute”. The above snippet was / is working fine until I introduced “IQuery”, resulting in the error thrown.
Incidentally - I saw your contribution [here](https://discourse.julialang.org/t/how-do-i-make-a-dispatch-table-using-multiple-dispatch-instead-of-dict/60784/21) and this StructTypes + Interface approach would potentially be applicable (I would post it if it worked…), since the OP is essentially making use of properties of a type rather than the type, with a default required for the generic: implying a conversion step on raw data (JSON?) to a type (or not) and an implementation of that method for the converted type to support multiple dispatch.
Like this:
```julia
#support calcs that allow streaming:
#default - fall through
streamingUpdate!(compute:: ICompute, value) = ()
function streamingUpdate!(ave:: Average, value)
if(ismissing(value)) return end
ave.runningTotal += value
ave.runningCount += 1
end
function streamingUpdate!(sum:: Sum, value)
if(ismissing(value)) return end
sum.runningTotal += value
end
```
Regards,
---
### Author:  [@Jeff\_Emanuel](https://discourse.julialang.org/u/Jeff_Emanuel)
#### Post date: [May 10, 2021, 7:06pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/4 "2021-05-10T19:06:29Z")
Maybe you need
> `StructTypes.subtypekey` that indicates which input key/field name should be used for identifying the appropriate concrete subtype.
defining “queryName” and “computeName”?
---
### Author:  [@djholiver](https://discourse.julialang.org/u/djholiver)
#### Post date: [May 10, 2021, 9:27pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/5 "2021-05-10T21:27:14Z")
Thanks - unfortunately not as simple - I already define this in the script above
Regards
---
### Author:  [@Jeff\_Emanuel](https://discourse.julialang.org/u/Jeff_Emanuel)
#### Post date: [May 10, 2021, 9:29pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/6 "2021-05-10T21:29:09Z")
Sorry, I didn’t notice it.
---
### Author:  [@djholiver](https://discourse.julialang.org/u/djholiver)
#### Post date: [May 11, 2021, 5:20pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/7 "2021-05-11T17:20:14Z")
No problem at all.
would you be able to see if the original code snippets run for you? Still at a loss whats going on.
@lmiq did the edits allow you to execute the snippets?
Regards
---
### Author:  [@Jeff\_Emanuel](https://discourse.julialang.org/u/Jeff_Emanuel)
#### Post date: [May 11, 2021, 5:32pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/8 "2021-05-11T17:32:58Z")
Both snippets fail for me with:
```julia
ERROR: LoadError: MethodError: no method matching length(::Type{Percentile})
Closest candidates are:
length(::Union{Base.KeySet, Base.ValueIterator}) at abstractdict.jl:58
length(::Union{LinearAlgebra.Adjoint{T, S}, LinearAlgebra.Transpose{T, S}} where {T, S}) at C:\buildbot\worker\package_win64\build\usr\share\julia\stdlib\v1.6\LinearAlgebra\src\adjtrans.jl:195
length(::Base.LogicalIndex) at multidimensional.jl:732
...
```
My versioninfo() is the same as your except minor hardware details.
---
### Author:  [@lmiq](https://discourse.julialang.org/u/lmiq)
#### Post date: [May 11, 2021, 5:51pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/9 "2021-05-11T17:51:04Z")
> [@djholiver](#):
>
> @leandromartinez98 did the edits allow you to execute the snippets?
Yes, but I don’t know how to solve the problem ☹
---
### Author:  [@djholiver](https://discourse.julialang.org/u/djholiver)
#### Post date: [May 11, 2021, 6:44pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/10 "2021-05-11T18:44:28Z")
Many thanks to you both for trying - very odd that it works for @lmiq across both snippets but not for @Jeff_Emanuel at all…
Must be down to package and / or Julia versions - I can still get one scenario to work!
I’ll revert if I find the solution / issue.
Regards,
---
### Author:  [@lmiq](https://discourse.julialang.org/u/lmiq)
#### Post date: [May 11, 2021, 6:47pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/11 "2021-05-11T18:47:54Z")
Oh, no, I meant that I can run the code, not that it works. I doesn’t work (I get the same error as you).
---
### Author:  [@Skoffer](https://discourse.julialang.org/u/Skoffer)
#### Post date: [May 11, 2021, 7:41pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/12 "2021-05-11T19:41:16Z")
It should be
```julia
function StructTypes.subtypes(::Type{ICompute})
(
percentile = Percentile,
)
end
```
---
### Author:  [@djholiver](https://discourse.julialang.org/u/djholiver)
#### Post date: [May 11, 2021, 8:07pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/13 "2021-05-11T20:07:08Z")
Thanks @Skoffer ! I was hoping it was something simple - very counter intuitive - is it something to do with Tuple definitions?
Thanks all for contributing.
Regards
---
### Author:  [@lhnguyen-vn](https://discourse.julialang.org/u/lhnguyen-vn)
#### Post date: [May 11, 2021, 10:58pm UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/14 "2021-05-11T22:58:35Z")
Parentheses are also used to specify order of operations, so an explicit comma is required to disambiguate that you’re constructing a tuple.
---
### Author:  [@Skoffer](https://discourse.julialang.org/u/Skoffer)
#### Post date: [May 12, 2021, 9:30am UTC](https://discourse.julialang.org/t/abstract-types-and-structtypes-error-reading-abstracttypes-into-concrete-with-json3/60897/15 "2021-05-12T09:30:07Z")
The way how it is written is slightly confusing, since tabs do not correspond to usual notations. If you rewrite your original code as
```julia
function StructTypes.subtypes(::Type{ICompute})
(percentile = Percentile)
end
```
Or even better
```julia
StructTypes.subtypes(::Type{ICompute}) = (percentile = Percentile)
```
then issue is more obvious. In expression `(percentile = Percentile)` brackets are ignored, so it is equivalent to `percentile = Percentile`, i.e. it creates throaway variable `percentile` and returns the result of assignment operator which is equals to `Percentile`. So, instead of returning `NamedTuple` function was equivalent to
```julia
StructTypes.subtypes(::Type{ICompute}) = Percentile
```
And of course, since type is not the same as `NamedTuple` `StructTypes` was unable to process it.
If you want to create named tuple with single field, you can either use comma after expression or semicolon at the beginning. So both will do
```julia
StructTypes.subtypes(::Type{ICompute}) = (percentile = Percentile, )
# or
StructTypes.subtypes(::Type{ICompute}) = (; percentile = Percentile)
```